[Sync] Lua Hyprland chain, licence cleanup

common/.config/fish/conf.d/agent-state.fish

@@ -0,0 +1,27 @@
+# Mark the tmux window when a long shell command finishes, through the same
+# ~/.config/tmux/scripts/agent-state.sh the coding agents use (tool tag "sh"):
+# ✓ on exit 0, ! on failure — coloured when it happened while you were elsewhere, grey once
+# visited, gone at the next command. Only commands longer than $agent_state_min_ms
+# (default 30 s) count, and interactive programs are skipped: the agents mark themselves,
+# and quitting a long nvim or lazygit session is not news. No-op outside tmux.
+set -q agent_state_min_ms; or set -g agent_state_min_ms 30000
+
+function __agent_state_preexec --on-event fish_preexec
+    set -q TMUX_PANE; or return
+    ~/.config/tmux/scripts/agent-state.sh sh busy
+end
+
+function __agent_state_postexec --on-event fish_postexec
+    set -l st $status # first statement: anything before it would clobber the command's status
+    set -q TMUX_PANE; or return
+    test "$CMD_DURATION" -gt "$agent_state_min_ms"; or return
+    switch (string split -m1 ' ' -- $argv[1])[1]
+        case nvim vim vi less man lazygit ssh mosh tmux claude claudes pi opencode opencodes codex aichat htop btop top journalctl tail watch
+            return
+    end
+    if test $st -eq 0
+        ~/.config/tmux/scripts/agent-state.sh sh done
+    else
+        ~/.config/tmux/scripts/agent-state.sh sh error
+    end
+end

common/.config/fish/conf.d/kitty-public-key.fish

@@ -0,0 +1,20 @@
+# Drop kitty's KITTY_PUBLIC_KEY from the shell environment.
+#
+# kitty generates a random 40-char base85 public key per instance and exports it
+# to every child (kitty/child.py). It is only read on the password path of kitty
+# remote control (kitty/remote_control.py: "Password usage requested but
+# KITTY_PUBLIC_KEY environment variable is not available"), which needs
+# allow_remote_control — not enabled here. `kitten ssh`, icat, clipboard and
+# shell integration never touch it.
+#
+# Why bother: tools that inline the environment into generated code get corrupted
+# when a value contains a String.replace replacement sequence. prettier's
+# --experimental-cli inlines JSON.stringify(process.env) into its parallel worker
+# and splices it with .replace(placeholder, bootloader); a `$` + backtick in the
+# key expands to "everything before the match", injecting the worker's own source
+# mid-string. Every file then fails with a bogus
+# "SyntaxError: Unexpected identifier 'string'". Roughly a 1-in-185 chance per
+# kitty launch, which is exactly as fun to debug as it sounds.
+if set -q KITTY_PUBLIC_KEY
+    set -e KITTY_PUBLIC_KEY
+end