[Sync] Lua Hyprland chain, licence cleanup

common/.config/fish/functions/glow.fish

@@ -0,0 +1,6 @@
+function glow --wraps glow --description 'glow wrapped at the current terminal width; an explicit -w still wins'
+    # glow never sizes itself to the terminal: glow.yml's width (or its built-in 80) applies, and
+    # `width: 0` in the config means 80 too. Wide tables get squeezed into that, one word per line.
+    # $COLUMNS tracks window resizes; a later -w/--width in $argv overrides this one.
+    command glow --width $COLUMNS $argv
+end

common/.config/fish/functions/md2pdf.fish

@@ -0,0 +1,11 @@
+function md2pdf --description 'Markdown to PDF next to the source: cmark-gfm renders it, headless chromium prints it'
+    # Relative image paths don't resolve (the HTML is rendered from /tmp), and chromium
+    # leaves out backgrounds when printing, so code blocks lose their grey box.
+    set -l html (mktemp --suffix=.html)
+    begin
+        echo '<meta charset="utf-8"><style>body{font-family:sans-serif;max-width:46em;margin:auto;line-height:1.5}table{border-collapse:collapse}td,th{border:1px solid #ccc;padding:.3em .6em}</style>'
+        cmark-gfm -e table -e strikethrough -e autolink -e tasklist $argv[1]
+    end >$html
+    chromium --headless --no-pdf-header-footer --print-to-pdf=(path change-extension pdf $argv[1]) $html 2>/dev/null
+    rm $html
+end