[Fix] cleanup

common/.config/fish/completions/c2-worktree.fish

@@ -0,0 +1,5 @@
+# Single positional arg: a branch name. It runs `git checkout -b`, so the new
+# branch is typically a fresh name -- but offer existing branch names as a base
+# to type from. Only suggest inside a git repo.
+complete -c c2-worktree -x -n 'git rev-parse --is-inside-work-tree 2>/dev/null' \
+    -a '(git for-each-ref --format="%(refname:short)" refs/heads refs/remotes 2>/dev/null | string replace -r "^origin/" "")'

common/.config/fish/completions/h.fish

@@ -0,0 +1,3 @@
+# `h <cmd> ...` shows a command's --help via bat, so complete it like a
+# command line: first token = a command, rest = that command's own args.
+complete -c h -x -a '(__fish_complete_subcommand)'

common/.config/fish/completions/pipx.fish

@@ -0,0 +1,17 @@
+
+function __fish_pipx_complete
+    set -x _ARGCOMPLETE 1
+    set -x _ARGCOMPLETE_DFS \t
+    set -x _ARGCOMPLETE_IFS \n
+    set -x _ARGCOMPLETE_SUPPRESS_SPACE 1
+    set -x _ARGCOMPLETE_SHELL fish
+    set -x COMP_LINE (commandline -p)
+    set -x COMP_POINT (string length (commandline -cp))
+    set -x COMP_TYPE
+    if set -q _ARC_DEBUG
+        pipx 8>&1 9>&2 1>&9 2>&1
+    else
+        pipx 8>&1 9>&2 1>/dev/null 2>&1
+    end
+end
+complete --command pipx -f -a '(__fish_pipx_complete)'

common/.config/fish/conf.d/fish-ssh-agent.fish

@@ -0,0 +1,7 @@
+if test -z "$SSH_ENV"
+    set -xg SSH_ENV $HOME/.ssh/environment
+end
+
+if not __ssh_agent_is_started
+    __ssh_agent_start
+end

common/.config/fish/conf.d/fish_frozen_key_bindings.fish

@@ -0,0 +1,3 @@
+set --global fish_key_bindings fish_vi_key_bindings
+
+set --erase --universal fish_key_bindings

common/.config/fish/conf.d/fish_frozen_theme.fish

@@ -0,0 +1,38 @@
+set --global fish_color_autosuggestion 4D5566
+set --global fish_color_cancel -r
+set --global fish_color_command 39BAE6
+set --global fish_color_comment 626A73
+set --global fish_color_cwd 59C2FF
+set --global fish_color_cwd_root red
+set --global fish_color_end F29668
+set --global fish_color_error FF3333
+set --global fish_color_escape 95E6CB
+set --global fish_color_history_current --bold
+set --global fish_color_host normal
+set --global fish_color_host_remote yellow
+set --global fish_color_keyword 39BAE6
+set --global fish_color_match F07178
+set --global fish_color_normal B3B1AD
+set --global fish_color_operator E6B450
+set --global fish_color_option B3B1AD
+set --global fish_color_param B3B1AD
+set --global fish_color_quote C2D94C
+set --global fish_color_redirection FFEE99
+set --global fish_color_search_match --background=E6B450
+set --global fish_color_selection --background=E6B450
+set --global fish_color_status red
+set --global fish_color_user brgreen
+set --global fish_color_valid_path --underline
+set --global fish_pager_color_background
+set --global fish_pager_color_completion normal
+set --global fish_pager_color_description B3A06D yellow
+set --global fish_pager_color_prefix normal --bold --underline
+set --global fish_pager_color_progress brwhite --background=cyan
+set --global fish_pager_color_secondary_background
+set --global fish_pager_color_secondary_completion
+set --global fish_pager_color_secondary_description
+set --global fish_pager_color_secondary_prefix
+set --global fish_pager_color_selected_background --background=E6B450
+set --global fish_pager_color_selected_completion
+set --global fish_pager_color_selected_description
+set --global fish_pager_color_selected_prefix

common/.config/fish/conf.d/fnm.fish

@@ -0,0 +1,7 @@
+# fnm — single init for all hosts (config.fish must NOT source fnm again:
+# every `fnm env | source` mints a fresh multishell dir onto PATH).
+# fnm may be pacman-installed (on PATH) or self-installed under ~/.local/share/fnm.
+test -d "$HOME/.local/share/fnm"; and fish_add_path -g "$HOME/.local/share/fnm"
+if command -q fnm
+    fnm env --use-on-cd --version-file-strategy local --shell fish | source
+end

common/.config/fish/config.fish

@@ -0,0 +1,113 @@
+## Shared fish config (all hosts). Host-specific bits live in host.fish (sourced at the end).
+## Secrets (e.g. DUSKADIY_API_KEY) go in conf.d/secrets.fish, which is gitignored.
+
+set -gx EDITOR nvim
+set -gx PAGER less
+set -gx QT_FONT_DPI 96
+set -gx PI_SKIP_VERSION_CHECK 1
+set -gx OPENCODE_CONFIG "$HOME/.config/opencode/openai-gpt.jsonc"
+set -gx MANPAGER "nvim +Man!"
+# fzf's built-in walker is the one search tool that ignores .ignore files, so point it at
+# fd, which honours them. fd still hides dotfiles by default everywhere else — this only
+# changes what fzf sees inside trees that opt in (e.g. ~/.dots/.ignore).
+set -gx FZF_DEFAULT_COMMAND 'fd --type f --strip-cwd-prefix'
+set -gx NEWT_COLORS 'root=black,black;window=black,black;border=white,black;listbox=white,black;label=blue,black;checkbox=red,black;title=green,black;button=white,red;actsellistbox=white,red;actlistbox=white,gray;compactbutton=white,gray;actcheckbox=white,blue;entry=lightgray,black;textbox=blue,black' # themes nmtui
+# set -gx BAT_THEME "Catppuccin Mocha"
+
+# Cursor / greeting
+set -g fish_greeting
+set -g fish_cursor_insert line
+set -g fish_cursor_default block
+set -g fish_cursor_visual underscore
+
+# Misc
+alias exti=exit
+alias dmz="cat ~/.config/fish/dmz.txt"
+alias nmatrix="neo-matrix -DS 3"
+alias grep="grep --color=auto"
+alias fzf="fzf --preview 'bat --color=always {}'"
+alias fzff="fzf --multi --preview 'bat --style=numbers --color=always {}' | xargs -n 1 nvim"
+abbr scrcpyz 'scrcpy -wSK -m 1920 --window-borderless --always-on-top --power-off-on-close --no-audio'
+
+# Git
+alias gti="git"
+alias gs="git status -s"
+alias gca="git add -p . && git commit"
+alias gd="git diff --word-diff"
+alias gl="git log --graph --show-signature"
+alias glog="git log --all --decorate --oneline --color --graph"
+alias gla="git log --all --decorate --oneline"
+alias gls="serie"
+alias gm="git merge"
+
+# List directory 
+alias ls='eza --icons --group-directories-first'
+alias l="ls -l"
+alias la="ls -a"
+alias lla="ls -la"
+alias lt="ls --tree"
+
+# Dotfiles + notes
+alias cdots="cd ~/.dots/"
+alias cpnotes="cd ~/sync/PersonalNotes/"
+alias cnotes="cd ~/sync/CojaDuska/Notes/"
+abbr notes "cnotes && nvim"
+abbr dots "cdots && nvim"
+abbr dotsync "cdots && ./bin/dotsync"
+abbr pnotes "cpnotes && nvim"
+abbr todo "cpnotes && nvim ToDoNext.md"
+abbr aliases "bat ~/.config/fish/config.fish"
+
+# Handy
+abbr cat "bat -p"
+abbr untar "tar -xf"
+abbr unarchive "atool -x"
+abbr copy wl-copy
+abbr img "kitten icat"
+abbr fm yazi
+abbr lg lazygit
+abbr gcommit "git diff HEAD | aichat -r commit"
+abbr aichatdel "rm ~/.config/aichat/sessions/*.yaml"
+abbr mkdir "mkdir -p"
+abbr faillock "sudo faillock --reset"
+abbr xremaps "sudo xremap ~/.config/xremap/config.yml"
+abbr pacs "sudo pacman -Syu --noconfirm"
+abbr yays "yay --noconfirm --sudoloop"
+abbr nmaps "sudo nmap -sn 192.168.0.0/24"
+abbr scrcpyc 'scrcpy -wSK -m 1920 --window-borderless --always-on-top --power-off-on-close'
+abbr scrcpys 'scrcpy -wS --power-off-on-close'
+abbr tts "tt -notheme -bold -showwpm -json"
+abbr tuioss "tuios --show-clock --show-keys --show-cpu --show-ram --confirm-quit"
+abbr keybinds "cd ~/.dots/ && nvim gui/.config/hypr/keybindings.conf"
+abbr vpnhome "sudo wg-quick up wg0"
+abbr vpnkralizec "sudo wg-quick up kralizec-wg0"
+abbr vpnsumadija "sudo wg-quick up sumadija-wg0"
+abbr ipadd "sudo ip route add 192.168.0.234 dev wg0"
+abbr aria2cs "aria2c -x 16 -k 1M"
+
+# Change-dir shortcuts
+abbr .. "cd .."
+abbr ... "cd ../.."
+abbr .3 "cd ../../.."
+abbr .4 "cd ../../../.."
+abbr .5 "cd ../../../../.."
+
+# Tool init (fnm is initialized once in conf.d/fnm.fish — don't source it again here)
+zoxide init --cmd cd fish | source
+fish_add_path $HOME/.cargo/bin $HOME/.local/bin
+
+# thefuck, lazy-loaded on first use (its --alias eval costs ~170ms of shell startup)
+function fuck
+    functions -e fuck
+    thefuck --alias | source
+    fuck $argv
+end
+
+# pnpm
+set -gx PNPM_HOME "$HOME/.local/share/pnpm"
+if not string match -q -- $PNPM_HOME $PATH
+    set -gx PATH "$PNPM_HOME" $PATH
+end
+
+# Per-host extras
+test -f ~/.config/fish/host.fish; and source ~/.config/fish/host.fish

common/.config/fish/dmz.txt

@@ -0,0 +1,30 @@
+                          .dO00Od'                          
+                         d00000000d.                        
+                        d0000000000k                        
+                        x0000000000O                        
+                         k000000000                         
+                           ;0000: Okc                       
+                                    kkc                     
+                                      kkc                   
+                                        dkl                 
+                                          okl               
+                                            lOl             
+                                              cOo.          
+ .lxkOOkxl.              .lxkOOkxl.             ;OoxkOOkxl. 
+'O00000000O,            'O00000000O,            '000000000O,
+O0000000000OddddddddddddO00000000000ddddddddddddO00000000000
+c0000000000c            :0000000000l            :0000000000l
+ .00000000.              .00000000'             '000000000' 
+                             00               'd0.          
+                             00             ,d0.            
+                             00           ,x0               
+                             00         :x0                 
+                             00       cxO                   
+                             00     ckO                     
+                           .c00l' ckk                       
+                         ck000000O0                         
+                        c0000000000o                        
+                        O00000000000                        
+                        .0000000000.                        
+                          ,000000:                          
+                             :c                             

common/.config/fish/fish_plugins

@@ -0,0 +1 @@
+danhper/fish-ssh-agent

common/.config/fish/functions/__ssh_agent_is_started.fish

@@ -0,0 +1,23 @@
+function __ssh_agent_is_started -d "check if ssh agent is already started"
+	if test -n "$SSH_CONNECTION"
+		# This is an SSH session
+		ssh-add -l > /dev/null 2>&1
+		if test $status -eq 0 -o $status -eq 1
+			# An SSH agent was forwarded
+			return 0
+		end
+	end
+
+	if begin; test -f "$SSH_ENV"; and test -z "$SSH_AGENT_PID"; end
+		source $SSH_ENV > /dev/null
+	end
+
+	if test -z "$SSH_AGENT_PID"
+		return 1
+	end
+
+	ssh-add -l > /dev/null 2>&1
+	if test $status -eq 2
+		return 1
+	end
+end

common/.config/fish/functions/__ssh_agent_start.fish

@@ -0,0 +1,5 @@
+function __ssh_agent_start -d "start a new ssh agent"
+  ssh-agent -c | sed 's/^echo/#echo/' > $SSH_ENV
+  chmod 600 $SSH_ENV
+  source $SSH_ENV > /dev/null
+end

common/.config/fish/functions/ask.fish

@@ -0,0 +1,3 @@
+function ask --description 'answer from cht.sh' 
+  curl -s https://cht.sh/$(string join '+' $argv[1..]) 
+end

common/.config/fish/functions/bashs.fish

@@ -0,0 +1,3 @@
+function bashs --description 'raw bash command'
+    bash -c "$argv"
+end

common/.config/fish/functions/c2-worktree.fish

@@ -0,0 +1,30 @@
+function c2-worktree
+    if test (count $argv) -ne 1
+        echo "Usage: c2-worktree <branch-name>"
+        echo "Example: c2-worktree package/package-update"
+        return 1
+    end
+
+    set branch $argv[1]
+
+    set root (git rev-parse --show-toplevel)
+    or return 1
+    set dir $root/.worktrees/(basename $branch)
+
+    mkdir -p $root/.worktrees
+    or return 1
+
+    git checkout -b $branch
+    or return 1
+
+    git checkout master
+    or return 1
+
+    git worktree add $dir $branch
+    or return 1
+
+    cd $dir
+    or return 1
+
+    pnpm i
+end

common/.config/fish/functions/clis.fish

@@ -0,0 +1,3 @@
+function clis --description 'fzf select cli'
+    eval (cat $HOME/.config/misc/clis.txt | command fzf --multi)
+end

common/.config/fish/functions/copy-commandline.fish

@@ -0,0 +1,18 @@
+function copy-commandline
+    set -l cmd (commandline)
+    if test -n "$cmd"
+        if type -q pbcopy
+            echo -n "$cmd" | pbcopy
+        else if type -q xclip
+            echo -n "$cmd" | xclip -selection clipboard
+        else if type -q wl-copy
+            echo -n "$cmd" | wl-copy
+        end
+        
+        # Provide brief visual feedback in the prompt
+        set -l original_cmd (commandline)
+        commandline -r "Copied!"
+        sleep 0.4
+        commandline -r "$original_cmd"
+    end
+end

common/.config/fish/functions/extract.fish

@@ -0,0 +1,23 @@
+function extract --description 'Extract any archive'
+    switch $argv[1]
+        case '*.tar' '*.tar.*' '*.tgz' '*.tbz2' '*.txz' # tar autodetects compression
+            tar xf $argv[1]
+        case '*.zip'
+            unzip $argv[1]
+        case '*.rar'
+            unrar x $argv[1]
+        case '*.7z'
+            7z x $argv[1]
+        case '*.gz'
+            gunzip -k $argv[1]
+        case '*.xz'
+            unxz -k $argv[1]
+        case '*.zst'
+            unzstd $argv[1]
+        case '*.bz2'
+            bunzip2 -k $argv[1]
+        case '*'
+            echo "Unknown extension: $argv[1]"
+            return 1
+    end
+end

common/.config/fish/functions/fish_greeting.fish

@@ -0,0 +1,5 @@
+function fish_greeting
+    #curl "wttr.in/Belgrade?format=%l:+%c+%t+|+%h+|+%w+|+(%%M+%m)\n"
+    test -r ~/.config/fish/greet.txt; and cat ~/.config/fish/greet.txt ## populated by cronjob
+    date +"📅 %d. %b 🕗 %H:%M - %A"
+end

common/.config/fish/functions/fish_prompt.fish

@@ -0,0 +1,14 @@
+function fish_prompt
+    if test -n "$SSH_TTY"
+        echo -n (set_color brred)"$USER"(set_color white)'@'(set_color yellow)(prompt_hostname)' '
+    end
+
+    echo -n (set_color blue)(prompt_pwd)' '
+
+    set_color -o
+    if fish_is_root_user
+        echo -n (set_color red)'# '
+    end
+    echo -n (set_color red)'❯'(set_color yellow)'❯'(set_color green)'❯ '
+    set_color normal
+end

common/.config/fish/functions/fish_right_prompt.fish

@@ -0,0 +1,161 @@
+function fish_right_prompt
+    set -l cmd_status $status
+    if test $cmd_status -ne 0
+        echo -n (set_color red)" $cmd_status"
+    end
+
+    if not command -sq git
+        set_color normal
+        return
+    end
+
+    # Get the git directory for later use.
+    # Return if not inside a Git repository work tree.
+    if not set -l git_dir (command git rev-parse --git-dir 2>/dev/null)
+        set_color normal
+        return
+    end
+
+    # Get the current action ("merge", "rebase", etc.)
+    # and if there's one get the current commit hash too.
+    set -l commit ''
+    if set -l action (fish_print_git_action "$git_dir")
+        set commit (command git rev-parse HEAD 2> /dev/null | string sub -l 7)
+    end
+
+    # Get either the branch name or a branch descriptor.
+    set -l branch_detached 0
+    if not set -l branch (command git symbolic-ref --short HEAD 2>/dev/null)
+        set branch_detached 1
+        set branch (command git describe --contains --all HEAD 2>/dev/null)
+    end
+
+    # Get the commit difference counts between local and remote.
+    command git rev-list --count --left-right 'HEAD...@{upstream}' 2>/dev/null \
+        | read -d \t -l status_ahead status_behind
+    if test $status -ne 0
+        set status_ahead 0
+        set status_behind 0
+    end
+
+    # Get the stash status.
+    # (git stash list) is very slow. => Avoid using it.
+    set -l status_stashed 0
+    if test -f "$git_dir/refs/stash"
+        set status_stashed 1
+    else if test -r "$git_dir/commondir"
+        read -l commondir <"$git_dir/commondir"
+        if test -f "$commondir/refs/stash"
+            set status_stashed 1
+        end
+    end
+
+    # git-status' porcelain v1 format starts with 2 letters on each line:
+    #   The first letter (X) denotes the index state.
+    #   The second letter (Y) denotes the working directory state.
+    #
+    # The following table presents the possible combinations:
+    # * The underscore character denotes whitespace.
+    # * The cell values stand for the following file states:
+    #   a: added
+    #   d: deleted
+    #   m: modified
+    #   r: renamed
+    #   u: unmerged
+    #   t: untracked
+    # * Cells with more than one letter signify that both states
+    #   are simultaneously the case. This is possible since the git index
+    #   and working directory operate independently of each other.
+    # * Cells which are empty are unhandled by this code.
+    # * T (= type change) is undocumented.
+    #   See Git v1.7.8.2 release notes for more information.
+    #
+    #   \ Y→
+    #  X \
+    #  ↓  | A  | C  | D  | M  | R  | T  | U  | X  | B  | ?  | _
+    # ----+----+----+----+----+----+----+----+----+----+----+----
+    #  A  | u  |    | ad | am | r  | am | u  |    |    |    | a
+    #  C  |    |    | ad | am | r  | am | u  |    |    |    | a
+    #  D  |    |    | u  | am | r  | am | u  |    |    |    | a
+    #  M  |    |    | ad | am | r  | am | u  |    |    |    | a
+    #  R  | r  | r  | rd | rm | r  | rm | ur | r  | r  | r  | r
+    #  T  |    |    | ad | am | r  | am | u  |    |    |    | a
+    #  U  | u  | u  | u  | um | ur | um | u  | u  | u  | u  | u
+    #  X  |    |    |    | m  | r  | m  | u  |    |    |    |
+    #  B  |    |    |    | m  | r  | m  | u  |    |    |    |
+    #  ?  |    |    |    | m  | r  | m  | u  |    |    | t  |
+    #  _  |    |    | d  | m  | r  | m  | u  |    |    |    |
+    set -l porcelain_status (command git status --porcelain 2>/dev/null | string sub -l2)
+
+    set -l status_added 0
+    if string match -qr '[ACDMT][ MT]|[ACMT]D' $porcelain_status
+        set status_added 1
+    end
+    set -l status_deleted 0
+    if string match -qr '[ ACMRT]D' $porcelain_status
+        set status_deleted 1
+    end
+    set -l status_modified 0
+    if string match -qr '[MT]$' $porcelain_status
+        set status_modified 1
+    end
+    set -l status_renamed 0
+    if string match -qe R $porcelain_status
+        set status_renamed 1
+    end
+    set -l status_unmerged 0
+    if string match -qr 'AA|DD|U' $porcelain_status
+        set status_unmerged 1
+    end
+    set -l status_untracked 0
+    if string match -qe '\?\?' $porcelain_status
+        set status_untracked 1
+    end
+
+    set_color -o
+
+    if test -n "$branch"
+        if test $branch_detached -ne 0
+            set_color brmagenta
+        else
+            set_color green
+        end
+        echo -n " $branch"
+    end
+    if test -n "$commit"
+        echo -n ' '(set_color yellow)"$commit"
+    end
+    if test -n "$action"
+        set_color normal
+        echo -n (set_color white)':'(set_color -o brred)"$action"
+    end
+    if test $status_ahead -ne 0
+        echo -n ' '(set_color brmagenta)''
+    end
+    if test $status_behind -ne 0
+        echo -n ' '(set_color brmagenta)''
+    end
+    if test $status_stashed -ne 0
+        echo -n ' '(set_color cyan)''
+    end
+    if test $status_added -ne 0
+        echo -n ' '(set_color green)''
+    end
+    if test $status_deleted -ne 0
+        echo -n ' '(set_color red)''
+    end
+    if test $status_modified -ne 0
+        echo -n ' '(set_color blue)''
+    end
+    if test $status_renamed -ne 0
+        echo -n ' '(set_color magenta)''
+    end
+    if test $status_unmerged -ne 0
+        echo -n ' '(set_color yellow)'═'
+    end
+    if test $status_untracked -ne 0
+        echo -n ' '(set_color white)'◼'
+    end
+
+    set_color normal
+end

common/.config/fish/functions/fish_user_key_bindings.fish

@@ -0,0 +1,15 @@
+function fish_user_key_bindings
+    # free Ctrl+S from terminal flow control (XOFF) so it can be bound below
+    stty -ixon
+    fish_default_key_bindings -M insert
+    fish_vi_key_bindings --no-erase insert
+    bind -M default ctrl-a beginning-of-line
+    bind -M default ctrl-e end-of-line
+    bind -M insert ctrl-space accept-autosuggestion
+    bind -M insert ctrl-g 'git diff' repaint
+    bind -M insert ctrl-o execute yazi
+    bind -M insert ctrl-l clear-screen ls repaint
+    bind -M default ctrl-s copy-commandline
+    bind -M insert ctrl-s copy-commandline
+    bind -M search ctrl-s copy-commandline
+end

common/.config/fish/functions/fzfh.fish

@@ -0,0 +1,7 @@
+function fzfh --description 'Search history with fzf'
+    history | fzf --query="$argv" --tac | read cmd
+    if test -n "$cmd"
+        echo $cmd
+        commandline -r $cmd
+    end
+end

common/.config/fish/functions/gcap.fish

@@ -0,0 +1,5 @@
+function gcap --description 'Git add, commit with message, and push'
+    git add .
+    and git commit -m "$argv"
+    and git push
+end

common/.config/fish/functions/h.fish

@@ -0,0 +1,3 @@
+function h --description "Colorized --help via bat"
+    $argv --help 2>&1 | bat --plain --language=help
+end

common/.config/fish/functions/lk.fish

@@ -0,0 +1,18 @@
+function lk --description 'linux knowledge' 
+	set -l DB "$HOME/projects/dmz/soft/lk/db.rec"
+	set -l passes 0
+	set -l count 0
+	set -l query ""
+
+	while test $passes -lt 2; and test $count -eq 0
+		set query (recsel "$DB" -p aim,tag | recsel -iq "$query" -CP aim,tag | sort -u | fzf --preview="recsel \"$DB\" -e \"aim~{}\" | bat")
+		if test -n "$query"
+			set count (recsel "$DB" -q "$query" -c)
+		end
+		set passes (math $passes + 1)
+	end
+
+	if test $count -eq 1
+		recsel "$DB" -q "$query" | recfmt -f "$HOME/projects/dmz/soft/lk/lists.fmt" | less
+	end
+end

common/.config/fish/functions/opencodes.fish

@@ -0,0 +1,24 @@
+function opencodes --description 'contained opencode' 
+  bwrap \
+    --unshare-all \
+    --new-session \
+    --clearenv \
+    --die-with-parent \
+    --share-net \
+    --dev /dev \
+    --proc /proc \
+    --ro-bind /usr /usr \
+    --ro-bind /lib /lib \
+    --ro-bind /lib64 /lib64 \
+    --ro-bind /bin /bin \
+    --ro-bind /etc /etc \
+    --ro-bind ~/.config/opencode ~/.config/opencode \
+    --tmpfs /tmp/node-compile-cache \
+    --bind ~/.local/state/opencode ~/.local/state/opencode \
+    --bind ~/.local/share/opencode ~/.local/share/opencode \
+    --bind "$(pwd)" "$(pwd)" \
+  opencode
+end
+
+
+

common/.config/fish/functions/ssh.fish

@@ -0,0 +1,7 @@
+function ssh
+    if type -q kitten
+        kitten ssh $argv
+    else
+        command ssh $argv
+    end
+end

common/.config/fish/functions/sshf.fish

@@ -0,0 +1,6 @@
+function sshf --description 'fzf-pick an ssh host from ~/.ssh/config'
+    # command fzf: bypass the fzf alias (its bat preview makes no sense for host names);
+    # skip `Host *` wildcard blocks and take every alias on multi-name Host lines
+    set -l host (awk '/^Host /{for (i = 2; i <= NF; i++) if ($i != "*") print $i}' ~/.ssh/config | command fzf)
+    test -n "$host"; and ssh $host
+end

common/.config/fish/functions/tuis.fish

@@ -0,0 +1,3 @@
+function tuis --description 'fzf select tui'
+    eval (cat $HOME/.config/misc/tuis.txt | command fzf --multi)
+end